The following %OMARUNAN macro is not installed in the autocall library.
For more information on the %OMARUNAN macro, please refer to:

http://support.sas.com/onlinedoc/913/getDoc/en/bisag.hlp/a003141873.htm

/*********************************************************************/
/*                                                                   */
/*  MACRO: OMARUNAN  SP4                                             */
/*                                                                   */
/*  USAGE:                                                           */
/*                                                                   */
/* %OMARUNAN( DestinationPath="C:/SAS/9.1/Lev1/SASBackup")           */
/*                                                                   */
/*  DESCRIPTION:                                                     */
/*    This macro will execute the source code in the                 */
/*    VarAnalyzeAll.source entry of the OMA_Varan catalog in the     */
/*    destinationPath directory. That source file was created by the */
/*    last execution of the omabakup macro which specified the same  */
/*    DestinationPath for the backup copies of the repositories.     */
/*    If Runanalysis=Y is specified on that macro then this job has  */
/*    already been run after the main repositories were put back     */
/*    online. Doing that runs the analysis on the same machine as    */
/*    metadata server which may impact it's performance. If the      */
/*    DestinationPath is accessible from another machine on the      */
/*    network (recommended), then best performance is obtained by    */
/*    not specifying runanalysis=Y on the omabakup job and using this*/
/*    macro on another machine to do the variable analysis against   */
/*    the backup copies.                                             */
/*                                                                   */
/*  PARAMETERS:                                                      */
/*     DestinationPath: The pathname of the directory where the      */
/*         backup copy was stored.                                   */
/*         Example: "C:/SAS/9.1/Lev1/SASBackup"                      */
/*                                                                   */
/*  NOTES:                                                           */
/*                                                                   */
/* HISTORY: Action                                       Date    Who */
/* ----------------------------------------------------------------- */
/* Initial implementation                                2004 sasjsw */
/*                                                                   */
/*********************************************************************/

%macro omabudef();
%global defaultDestinationPath;
%if (&sysscp=WIN or &sysscp=DNTHOST) %then
%do;
  %let defaultDestinationPath="C:/SAS/9.1/Lev1/SASBackup";
%end;
%else
%do;
   %if &sysscp=OS %then
   %do;
      %let defaultDestinationPath="/usr/lpp/SAS/9.1/Lev1/SASBackup";
   %end;
   %else
   %do;
      %let HOME=%sysget(HOME);
      %let defaultDestinationPath="&HOME/SAS/9.1/Lev1/SASBackup";
   %end;
%end;
%mend;
%omabudef();

%macro BACKLIB(reposname);
%if &sysscp=WIN OR &sysscp=DNTHOST %then
  libname BACKLIB "%unquote(&destinationPath\&reposname)";
%else
  libname BACKLIB "%unquote(&destinationPath/&reposname)";
%mend;

%macro OMARUNAN(
          DestinationPath=&defaultDestinationPath);
%put NOTE: OMARUNAN - Running Variable analysis on backup repositories.;
%put NOTE: DestinationPath=&DestinationPath;

/* First, Validate destinationPath is an existing directory */
/* Drop any surrounding quotes; translate path separators.  */
%let temp=%sysfunc(translate(&DestinationPath, %str(  ),%str(%'%")));
%let DestinationPath=%qcmpres(&temp);
%let testDestPath=%superq(DestinationPath);
%if (&sysscp=WIN or &sysscp=DNTHOST) %then
  %let testDestPath=%sysfunc(translate(&testDestPath,
                 "\","/"));
%put NOTE: Testing that &testDestPath exists;
%if (&testDestPath eq "") OR %sysfunc(fileexist(&testDestPath)) = 0
%then
%do;
   %put ERROR: Did not locate Destination path "&testDestPath". No
analysis run;
   %abort return 12;
%end;

options nocenter linesize=128;

libname backdest "%unquote(&testDestPath)";
/* backdest used to access code created by last omabakup */

filename OMAVARAN  catalog 'backdest.OMA_Varan.VarAnalyzeAll.source';
%include OMAVARAN;

%mend;

Operating System and Release Information